Tech Arsenal 1/Tech Arsenal (Arsenal Computer).ISO/tek-04/tm480.zip/INSTALL.TSK

Text File | 1991-10-22 | 27KB | 1,061 lines

;Taskmaster installer: Written Aug 1991 by Steve Johnson/Mike Eastham.

go 1DATA        ;data definitions at end of task
1START

display cls
move true to hide
dir 'INSTALL.OVR'
if not found
  insert filename filename
  put no_forms nowait
  stop 1
fi

forms install.ovr
insert tversion iversion ldate
put foreword nowait ul
inkey char
insert iversion
if build@ = 1
  insert professional
else
  insert shareware
fi
insert tversion
put welcome nowait ul
move ldspec to char
if not ldspec ct 'tm.exe' or char > 'B'
  combine ldspec 68 into dest
  insert dest
  put wrongtm nowait
  stop 2
fi
dir ldspec
if found
  move display to lmess
  clear refdate crud refname
  move zero to delim
  setscan lmess 22
  scan refdate crud refname
  if refname ct zero
    sizevar refname fcol
  fi
fi
move ddrive to orig_drive
if comspec ne null
  dir comspec
  if not found
    insert comspec
    put bad_comspec nowait
    stop 3
  fi
else
  dir 'C:\COMMAND.COM'
  if not found
    put no_comspec nowait
    stop 4
  fi
fi
if fmpdir ne null
  combine fmpdir 68 into dest
  insert dest
  move 'dest1' to formname
else
  combine 'C:\FMP' 68 into dest
  move 'dest2' to formname
fi
fieldfill dest
put formname nodata noclear
clear pathok
until pathok
  fieldfill dest
  put formname nodisp noclear
  if funkey = 10
    stop 5
  fi
  if funkey = 1
    popfree sid
    popscreen sid
    put dirhelp nowait ul
    inkey char
    popdown sid
  else
    get dest
    move dest to char
    upper char
    if dest sw '~:\' and char >= 'A' and char <= 'Z' and char <> ddrive
      move true to pathok
    fi
  fi
fi
replace all '\\' of dest with '\'
trim dest
upper dest
select dest
user dest
if resp = 0
  move 'Already exists' to message
else
  dir dest
  if found
    put file_name nowait ul
    stop 6
  fi
  run 'mkdir ' dest
  user dest
  if resp ne 0
    put cant_create nowait ul
    stop 7
  fi
  move 'Created successfully' to message
fi
dspace
move display to dest_space
insert dest message dest_space

if dest_space < max_space
  if dest_space < min_space
    move 'noroom' to formname
  else
    move 'someroom' to formname
  fi
else
  move 'muchroom' to formname
fi

clear proceed
move 'Y' to char2
fieldfill char2
put formname nodata noclear
until proceed
  fieldfill char2
  put formname nodisp noclear
  get char2
  if funkey = 1
    popfree sid
    popscreen sid
    put spacehelp nowait ul
    inkey char
    popdown sid
  else
    move char2 to proceed
    if not proceed
      stop 8
    fi
  fi
fi
if build@ = 1            ;Taskmaster Professional
  move 10 to product_entry
fi
if build@ = 2            ;Registered shareware
  move 5 to product_entry
fi
move product_entry to i
clear file j
find corefiles = file        ;add names of relevant archive files
until j = filesets        ;to the corelist
  if entry i of options = 'A'
    move entry j of archives to file
    trim file
    combine file '.EXE' into entry row of corefiles
    increment row
  fi
  increment i
fi j
insert entry build@ of product_names
put filecheck nowait
select orig_drive
move 6 to column
move 13 to line
move 'x' to file
until file = spaces
  move entry count of corefiles to file
  if file <> spaces
    cursor line column file
    trim file
    dir file
    if found
      if file ct '.exe'
        move display to lmess
        clear crud
        move zero to delim
        setscan lmess 22
        scan crud
        if crud ne refdate
          move true to inconsistant
        fi
      fi
      fore 14
      display 1 tick 1
      fore 15
    else
      increment missing
    fi
    add 16 to column
    if column > 64
      move 6 to column
      increment line
    fi
  fi
fi count
if missing ne 0
  put files_missing nowait
  stop 9
fi
if inconsistant
  put files_inconsistant nowait
  stop 11
fi
wait 1
move product_entry to j
clear i
until choice <> 0
  increment i
  if entry j of options = 'A'
    move i to choice
  fi
fi j
put menu nodata nowait
move product_entry to i
move menutop to line
clear j
fore 14
until j = filesets
  if entry i of options = 'U'
    cursor line legendpos na
  fi
  increment i line
fi j
fore 15
display dsb
move '1CHECK1' to return_loc
select dest
user dest
clear fileset
move product_entry to i
until fileset = filesets
  if entry i of options = 'A'
    go 1CHECK
1CHECK1
  fi
  increment i
fi fileset
display enb
move 0f800h to bbmask
clear bbdisp
menu 1,menu
option 1,31
  popfree sid
  popscreen sid
  move 8000h to bbmask
  move hilite to main_choice
  move lasthelp to choice
  menu 11,help
  option 11,30 ;esc
  move hilite to lasthelp
  popdown sid
  move main_choice to choice
  clear bbdisp
  fore 15
  back 0
  return 1
  option 11,default
  move display to formname
  trim formname
  put formname nowait
  clear bbdisp
  return
option 1,32
  popfree sid
  popscreen sid
  display cls
  run 'dir/w'
  wait
  popdown sid
  clear bbdisp
  move hilite to choice
  return
option 1,1,5
  popfree sid
  popscreen sid
  clear bbdisp vidline
  subtract 1 from choice giving fileset
  add fileset to menutop giving optline
  scanvid optline giving vidline
  add fileset to product_entry giving i
  if entry i of options = 'U'
    return
  fi
  move zero to delim
  clear char
  setscan vidline legendpos
  scan char
  if char = tag or char = partial
    insert display dest
    put already_installed nowait
    inkey char
    popdown sid
    move true to bbdisp
    move 6 to choice
    return
  fi
  scanvid menutop giving vidline
  if not vidline ct tag and choice = 2 or choice = 3
    put badorder nowait ul
    inkey char
    popdown sid
    return
  fi
  combine orig_drive ':' entry fileset of archives into unpack
  display cls
  run unpack
  clear vidline
  scanvid 0 giving vidline
  if vidline ct 'bad command' or resp <> 0
    popdown sid
    insert unpack
    put badarc nowait ul
    inkey char
    popdown sid
    return
  fi
  clear i vidline
  until i = 23
    scanvid i giving vidline
    if vidline sw '[Y/N] N' or vidline ct '^C'
      popdown sid
      fore 15
      back 0
      return
    fi
  fi i
  popdown sid
  put info nowait
  if fileset <> 1 and fileset <> 2
    cursor 3 6 time '  Installing essential files ...'
    clear count
    move 1 to mask
    until count = essential
      move entry count of essential_files to file
      upper file
      trim file
      if file <> 'SCR.EXE'
        cursor 4 6 40
        combine 'COPY ' orig_drive ':\' file ' /v >nul' into command
        cursor 4 6 time 2 command
        run command
      fi
      attrib set mask file
    fi count
  fi
  display dsb
  move fileset to char
  find issue_files sw char
  add 1 to row giving count
  move 'x' to file
  cursor 3 6 time '  Creating screen template files with SCR ...'
  until file = spaces
    move entry count of issue_files to file
    move file to char
    if file ne spaces and char >= 'a' and char <= 'z'
      upper file
      trim file
      move file to ovrfile
      replace '.TSK' of ovrfile with '.OVR'
      replace '.MAC' of ovrfile with '.OVR'
      cursor 4 6 40
      cursor 4 6 time '  SCR ' file '/Q'
      run 'scr ' file '/q >nul:'
      if elevel <> 0
        display enb
        insert ovrfile file
        put badmac noclear ul
        get proceed
        if not proceed
          stop 10
        fi
      fi
    fi
  fi count
  fore 15
  back 0
  dspace
  popdown sid
  cursor freeline 36 display
  move '1CHECK2' to return_loc
  go 1CHECK
1CHECK2
  popfree sid
  popscreen sid
  if missing = 0
    move true to installed
  fi
  display enb
  return
option 1,6
  move true to deleting
  move '1CHECK3' to return_loc
  clear fileset
  move product_entry to i
  until fileset = filesets
    if entry i of options = 'A'
      go 1CHECK
1CHECK3
    fi
    increment i
  fi fileset
  find issue_files sw '99'
  move '2CHECK1' to return_loc
  go 2CHECK
2CHECK1
  popfree sid
  popscreen sid
  fore 15
  back 0
  clear bbdisp deleting
  return
option 1,33        ;function key 3
  popfree sid
  popscreen sid
  select orig_drive
  run 'list vendor.doc'
  select dest
  popdown sid
  clear bbdisp
  move hilite to choice
  return
option 1,34        ;function key 4
  clear bbdisp
  if hilite > filesets
    move hilite to choice
    return
  fi
  popfree sid
  popscreen sid
  cursor 8 20 3 'Fileset: ' display 4
  cursor 23 35 mark
  move hilite to main_choice
  subtract 1 from hilite giving fileset
  move fileset to char
  find issue_files sw char
  add 1 to row giving count
  move 'x' to file
  clear i inserts
  until file = spaces
    move entry count of issue_files to file
    if file <> spaces
      upper file
      move file to entry i of inserts
      increment i
    fi
  fi count
  move true to bbdisp
  clear choice
  move 8000h to bbmask
  menu 3,showfileset,inserts
  option 3,1,25
    combine '.' display into selection
    trim selection
    move '\' to delim
    clear i desc descs
    if filedescs ct selection
      setscan filedescs fcol
      scan file
      until desc = null
        clear desc
        scan desc
        trim desc
        if desc <> null
          move desc to entry i of descs
        fi
      fi i
    fi
    insert descs
    display dsb
    put filedet nowait ul
    display enb
    clear bbdisp
    return
  option 3,30
    popdown sid
    move main_choice to choice
    clear bbdisp
    return 1
  endm 3
endm 1

1CHECK
  clear missing located mask
  add menutop to fileset giving optline
  fore 14
  cursor optline busypos ptr
  move fileset to char
  find issue_files sw char
2CHECK
  add 1 to row giving count
  move 'x' to file
  until file = spaces
    move entry count of issue_files to file
    move file to char
    if file ne spaces
      clear deleted
      increment located
      upper file
      trim file
      dir file
      if resp = 0
        if deleting
          attrib set mask file        ;unset all attributes
          if file ct '*'
            run 'del ' file
          else
            erase file
          fi
          increment missing
          move true to deleted
        fi
      else
        increment missing
      fi
      if deleting and char >= 'a' and char <= 'z'
        replace '.TSK' of file with '.OVR'
        replace '.MAC' of file with '.OVR'
        dir file
        if found
          attrib set mask file        ;unset all attributes
          erase file
          move true to deleted
        fi
      fi
      if deleted
        dspace
        cursor freeline 36 display
      fi
    fi
  fi count
  cursor optline busypos 1
  if return_loc ne '2CHECK1'
    cursor optline legendpos
    if missing = 0
      display tag
    else
      if missing < located
        display partial
      else
        display 1
      fi
    fi
  fi
  fore 15
  dspace
  cursor freeline dircol 'Free bytes on install drive = ' display
  cursor dirline dircol dest
  goback return_loc

option 1,30        ;escape key
  trim dest
  move dest to char
  combine char ':\FMP.BAT' into file
  clear count
  behave 3 file
  move dashes to lmess
  data 'echo off' crlf
  data 'echo ' lmess crlf
  data 'ECHO FmP INSTALL: Suggested changes to be applied to AUTOEXEC.BAT:' crlf
  data 'ECHO (based on the environment existing when INSTALL was run)' crlf
  data 'ECHO After applying the changes; this file (FMP.BAT) will not be required.' crlf
  data 'echo ' lmess crlf
  move $prompt to char
  if char = null
    increment count
    data 'echo ' count '. Add a PROMPT command like: "PROMPT $p$g"' crlf
    data 'PROMPT $p$g' crlf
    data 'echo ' lmess crlf
  fi
  move $path to workline
  if workline = null
    increment count
    data 'echo ' count '. Add a PATH command like: "PATH ' dest '"' crlf
    data 'PATH ' dest crlf
    data 'echo ' lmess crlf
  else
    if not workline ct dest
      increment count
      data 'echo ' count '. Add ";' dest '" to your existing PATH command' crlf
      data 'PATH ' $PATH ';' dest crlf
      data 'echo ' lmess crlf
    fi
  fi
  move $append to workline
  if workline = null
    increment count
    data 'echo ' count '. The first APPEND command should be "APPEND /E"' crlf
    data 'echo ' lmess crlf
    increment count
    data 'echo ' count '. Add ";' dest '" to your existing APPEND command if you have one' crlf
    data 'echo        else add the command "APPEND ' dest '"' crlf
    data 'echo ' lmess crlf
  else
    if not workline ct dest
      increment count
      data 'echo ' count '. Please add ";' dest '" to your existing APPEND command' crlf
      data 'APPEND ' $APPEND ';' dest crlf
      data 'echo ' lmess crlf
    fi
  fi
  move $fmpdir to workline
  if workline = null
    increment count
    data 'echo ' count '. Please add the command:' crlf
    data 'echo        "SET FMPDIR=' dest '"' crlf
    data 'SET FMPDIR=' dest crlf
    data 'echo ' lmess crlf
  else
    if not workline ct dest
      increment count
      data 'echo ' count '. Please update your set command to:' crlf
      data 'echo        "SET FMPDIR=' dest '"' crlf
      data 'SET FMPDIR=' dest crlf
      data 'echo ' lmess crlf
    fi
  fi
  if count = 0
    data 'echo System is set up as per FmP advice' crlf
  fi
  data 'echo ' lmess crlf
  move dest to char
  data char ':' crlf
  data 'CD ' dest crlf
  data 'ECHO Please enter "TM OVERVIEW<return>" to run Taskmaster' crlf
  data 'echo ' lmess crlf
  data 'echo on'
  behave 0
  insert file
  if installed
    put info1 nowait ul
  else
    put info2 nowait ul
  fi
  stop

1DATA

var iversion,5,'V1.00'
var tversion,5,'V4.80'
var crud,4
var refdate,4
var refname,12

define busypos,5    ;column number for busy marker
define dirline,21    ;line number for directory name
define dircol,6        ;column number for directory name
define essential,9    ;number of essential files
define filesets,5    ;number of filesets
define freeline,20    ;line number for 'free space' message
define legendpos,36    ;column number for status legend
define menutop,12    ;first line of main menu

hexvar crlf,0d0a    ;carriage-return/linefeed
hexvar esc,1b        ;escape character
hexvar mark,1f        ;block down arrow
hexvar na,16        ;'not available' symbol
hexvar ptr,10        ;'checking' symbol
hexvar partial,0c    ;'partial install' symbol
hexvar tag,0f        ;'installed' symbol
hexvar tick,fb        ;'tick' symbol

int att            ;file attribute
int column        ;gp cursor column
int count        ;gp counter
int i,j            ;gp counters
int fcount        ;counter used on mono only
int fileset            ;fileset indicator
int lasthelp        ;last help selection topic number
int line        ;gp cursor line number
int located        ;number of files in fileset
int mask        ;attribute bits used with attrib command
int main_choice        ;copy of menu choice
int missing        ;number of files missing from a fileset
int optline        ;line number within menu
int product_entry    ;start offset within options table for product
int sid            ;popup identifier

logical inconsistant    ;set when not all exe files time/date match
logical deleted        ;set when file deleted
logical deleting    ;set when deleting a fileset
logical guess_reg    ;set if I think TM is registered shareware
logical installed    ;set when a product has been installed
logical pathok        ;set when installation directory is valid
logical proceed        ;gp progress state

var char,1            ;gp
var char2,1            ;gp
var command,40
var professional,12,'Professional'
var comspec,68,$COMSPEC        ;environment variable
var desc,68            ;file description line
var descs,68,occurs4        ;complete file description
var dest,68,'C:\FMP'        ;default installation directory
var dest_space,12        ;character string free space
var lmess,70            ;long message - for .bat file
var file,12            ;gp
var fname,14            ;only used if mono
var ovrfile,12            ;name of file to generate with SCR
var filename,8,' INSTALL'    ;name of this task
var fmpdir,68,$fmpdir        ;environment variable
var formname,20            ;holds scr form names
var inserts,12,occurs20        ;menu of files in fileset
var max_space,12,'     1300000'    ;maximum disc space required
var message,40
var min_space,12,'      500000'    ;minimum disc space required
var null,1            ;gp
var orig_drive,1        ;drive identifier of floppy
var selection,16
var shareware,12,'Shareware   '    ;inserted into sign-on screen
var return_loc,7        ;dynamic labels
var textline,80            ;for reading file descriptions
var unpack,12            ;name of self-extracting archive file
var vidline,80            ;holds contents of one screen line
var workline,200                ;workarea

vconst cel,55            ;clear to end of line
vconst cep,56            ;clear to end of screen
vconst cls,11            ;clear screen
vconst enb,74            ;enable cursor
vconst dsb,75            ;disable cursor
vconst block,101        ;enable block cursor

;TABLES

var options,1,occurs 15,
'AAAUU'        ;Unregistered shareware
'UUUAU'        ;Registered shareware
'UUUUA'        ;Taskmaster Professional

var product_names,33,occurs 4,
'                                 '
'Taskmaster Professional          '
'Registered Shareware Taskmaster  '
'Unregistered Shareware Taskmaster'

var essential_files,12,occurs9,
'FMPVT52.DEF '
'TM.EXE      '
'LIST.COM    '
'LOGON.OVR   '
'SCR.EXE     '
'VENDOR.DOC  '
'INSTALL.TSK '
'INSTALL.OVR '
'LICENCE.FMP '

var archives,8,occurs 5,
'TMISSUE '
'TMEXAM  '
'TMMANUAL'
'TMREG   '
'TMPRO   '

;files starting in lowercase require processing with SCR

var issue_files,12,occurs 100,
'0           '
'CATALOGV.EUC'        ;Unregistered shareware
'CATALOG.EUC '
'CONFIG.TMS  '
'cONFIG.TSK  '
'EXAMPLES.TMS'
'FMPVT52.DEF '
'LICENCE.FMP '
'LIST.COM    '
'LOGON.OVR   '
'oVERVIEW.MAC'
'OVERVIEW.TSK'
'README.FMP  '
'SCR.EXE     '
'SHARETM.FMP '
'iNTRO.MAC   '
'INTRO.TSK   '
'sMART.TSK   '
'sTANDARD.TSK'
'VENDOR.DOC  '
'TM.EXE      '
'            '
'1           '
'bROWSE.TSK  '        ;Examples
'dIRECTOR.TSK'
'hELP.MAC    '
'HELP.TSK    '
'hOTEMENU.TSK'
'hVMENU.TSK  '
'mENUONE.TSK '
'NATO.TSK    '
'sWEEP.TSK   '
'tEST.TSK    '
'tMDEV.TSK   '
'wHEREIS.TSK '
'wORDPROC.TSK'
'            '
'2           '
'pRINTMAN.TSK'         ;Manuals
'pRINTSCR.TSK'
'sCRMAN.MAC  '
'SCRMAN.TSK  '
'tMMAN.MAC   '
'TMMAN.TSK   '
'            '
'3           '
'CATALOGV.EUC'        ;Registered Shareware
'CATALOG.EUC '
'CONFIG.TMS  '
'cONFIG.TSK  '
'EUC.EXE     '
'EUC.OVR     '
'EUC.PIN     '
'FMPVT52.DEF '
'LIST.COM    '
'LOGON.OVR   '
'SCR.EXE     '
'sMART.TSK   '
'sTANDARD.TSK'
'TIDY.EXE    '
'TM.EXE      '
'            '
'4           '
'CATALOGV.EUC'        ;Taskmaster Professional
'CATALOG.EUC '
'CONFIG.TMS  '
'cONFIG.TSK  '
'EUC.EXE     '
'EUC.OVR     '
'EUC.PIN     '
'FMPVT52.DEF '
'LIST.COM    '
'LOGON.OVR   '
'SCR.EXE     '
'sMART.TSK   '
'sTANDARD.TSK'
'TIDY.EXE    '
'TM.EXE      '
'            '
'99          ' ;removed if found
'TMISSUE.EXE '
'TMISSUE.COM '
'TMEXAM.EXE  '
'TMEXAM.COM  '
'TMMANUAL.EXE'
'TMMANUAL.COM'
'INSTALL.OVR '
'INSTALL.TSK '
'*.OVR       '
'EUC.PIN     '
'EUC.EXE     '
'TIDY.EXE    '

var corefiles,12,occurs 13,
'FMPVT52.DEF '
'GO.BAT      '
'INSTALL.OVR '
'INSTALL.TSK '
'LICENCE.FMP '
'LIST.COM    '
'LOGON.OVR   '
'TM.EXE      '
'VENDOR.DOC  '

;Issue file descriptions. No line must exceed 68 characters and each
;must terminate with a '\' Maximum of 4 lines per file description.

var filedescs,7000,
'.BROWSE.TSK\'
'Example task that displays the names of files in selected directory\'
'and allows built-in and user-configured operations to be performed\'
'on them.\'
'\'
'.CATALOGV.EUC\'
'This is a backup copy of CATALOG.EUC so that you can restore the\'
'file CATALOG.EUC if required.\'
'\'
'.CATALOG.EUC\'
'A sample encrypted catalogue of usernames and passwords for use with\'
'the EUC package. Used by example tasks STANDARD.TSK and SMART.TSK.\'
'\'
'.CONFIG.TMS\'
'A sample service configuration file created by CONFIG.TSK and read\'
'by STANDARD.TSK.  The file can be modified using CONFIG.TSK\'
'\'
'.CONFIG.TSK\'
'This task enables you to configure one or more sets of end-user\'
'services. The service information so provided is then accessed\'
'by STANDARD.TSK which presents the end-user with menus to access\'
'these services.\'
'\'
'.DIRECTOR.TSK\'
'This task runs the DOS DIR command, captures its output in a file\'
'and then displays it in on the screen in colour.\'
'\'
'.EUC.EXE\'
'EUC is the End User Computing option and is provided as a PROTEAN\'
'runtime system, i.e. it is written in the PROTEAN (C) 4GL language.\'
'It enables a system administrator to catalogue,maintain, support\'
'and monitor a group of end-users.\'
'\'
'.EUC.OVR\'
'This file is produced by SCR.EXE and contains screen templates used\'
'by EUC.EXE\'
'\'
'.EUC.PIN\'
'This file contains PROTEAN generated code, i.e. a compiled program\'
'which is executed when EUC.EXE is run.\'
'\'
'.EXAMPLES.TMS\'
'This is a further sample set of services for use with STANDARD.TSK.\'
'See also CONFIG.TMS\'
'\'
'.FMPVT52.DEF\'
'A file containing VT52 escape sequences supported by the Taskmaster\'
'VT52 driver. VT52 is a video protocol used to control the display of\'
'data on your screen.\'
'\'
'.HELP.MAC\'
'This file holds source screen templates for use with HELP.TSK. The\'
'file has to be processed by SCR.EXE before the screens can be used.\'
'The installer runs SCR to produce HELP.OVR \'
'\'
'.HELP.TSK\'
'An example task that demonstrates the use of colour and windows in\'
'screen templates and how easy it is to create help and information\'
'screens for end-users.\'
'\'
'.HOTEMENU.TSK\'
'A simple example task demonstrating the use of bounce-bar menus and\'
'how to provide a context sensitive help system.\'
'\'
'.HVMENU.TSK\'
'This example task demonstrates the use of horizontal and vertical\'
'bounce-bar menus by way of a simple game that involves you in\'
'guessing the correct combination to a safe. It also shows how simple\'
'but effective line graphics can be produced using SCR.\'
'\'
'.INTRO.MAC\'
'Holds the source screen templates required by INTRO.TSK.\'
'\'
'.INTRO.TSK\'
'This is a multi-level menu system that provides a detailed insight\'
'into Taskmaster and describes its many applications.\'
'\'
'.LICENCE.FMP\'
'This is the end-user license agreement.  It details conditions of\'
'use for Shareware Taskmaster and the terms under which it may be\'
'evaluated and distributed.\'
'\'
'.LIST.COM\'
'A public domain file viewer.\'
'\'
'.LOGON.OVR\'
'A file containing internal screen templates required by Taskmaster.\'
'\'
'.MENUONE.TSK\'
'This  task  is an example of a simple menu which uses  the  SAVE \'
'and RESTORE commands to remember the names of several applications.\'
'\'
'.NATO.TSK\'
'An example task that reads the text you type and converts it into\'
'the NATO Phonetic alphabet. Demonstrates generalised capabilities\'
'of the Taskmaster JCL.\'
'\'
'.OVERVIEW.MAC\'
'Holds the source screen templates required by OVERVIEW.TSK.\'
'\'
'.OVERVIEW.TSK\'
'This task is provided as a top-level interface to all the supplied\'
'tasks. It is therefore recommended that you load this task first if\'
'evaluating Taskmaster for the first time.\'
'\'
'.PRINTMAN.TSK\'
'This task will print all or parts of the Taskmaster on-line manual.\'
'Because the manual contains line graphics, your printer will need\'
'to support the IBM character set.\'
'\'
'.PRINTSCR.TSK\'
'This task will print all or parts of the SCR on-line manual.\'
'Because the manual contains line graphics, your printer will need\'
'to support the IBM character set.\'
'\'
'.README.FMP\'
'Printable details of files supplied with the evaluation disc and\'
'its system requirements.\'
'\'
'.SCRMAN.MAC\'
'Holds the source screen templates required by SCRMAN.TSK.\'
'\'
'.SCRMAN.TSK\'
'This task offers an on-line manual for the SCR product. The screens\'
'are held in SCRMAN.MAC and processed by SCR into SCRMAN.OVR\'
'\'
'.SCR.EXE\'
'This is the screen template processor program; essential for the\'
'rapid construction of menus, data-capture and help screens etc.\'
'The screens displayed by this Installer were created using SCR.\'
'\'
'.SHARETM.FMP\'
'Printable Details of the examples\'
'\'
'.SMART.TSK\'
'This task is an alternative example of a configurable menu system.\'
'Like STANDARD.TSK, it also interfacew with the EUC Catalogue for\'
'user-login and password verification.\'
'\'
'.STANDARD.TSK\'
'See also CONFIG.TSK.  STANDARD.TSK is a pre-written task providing\'
'an end-user menu interface to services (applications) configured\'
'using CONFIG.TSK.  It offers a range of customisation features for\'
'each service.  Use it if you do not wish to write your own task.\'
'\'
'.SWEEP.TSK\'
'As its name implies, this task sweeps the directory structure for\'
'all files matching a wildcard specification and optionally writes\'
'their names to a .BAT file. Each filename can be sustituted into\'
'a DOS command if required.\'
'\'
'.TEST.TSK\'
'This is a skeletal task for use with TMDEV.TSK\'
'\'
'.TIDY.EXE\'
'This program examines a .TSK file (Taskmaster JCL file) and reforms\'
'its block structure in a consistent manner.\'
'\'
'.TMDEV.TSK\'
'An example of a simple development harness. This particular harness\'
'allows you to develop Taskmaster tasks but could be easily changed\'
'to support any language\'
'\'
'.TMMAN.MAC\'
'Holds the source screen templates required by TMMAN.TSK.\'
'\'
'.TMMAN.TSK\'
'This task provides an on-line manual for the Taskmaster JCL.\'
'Screens are held in SCRMAN.MAC and processed by SCR into TMMAN.OVR\'
'\'
'.TM.EXE\'
'This is either the Unregistered shareware, Registered shareware or\'
'Professional version. The installer you have loaded is a task which\'
'is currently being interpreted by TM.EXE\'
'\'
'.WHEREIS.TSK \'
'Searches for a named file using the same algorithm as DOS uses\'
'when asked to locate files.  It helps to pin-point the actual \'
'copy DOS will use when multiple copies exist\'
'\'
'.WORDPROC.TSK\'
'A Wordprocessing harness that stores details about your\'
'wordprocessor or text editor and descriptions and edit times of\'
'your most recently used files.\'
'\'

end
goback 1START

endtask